***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 21, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PJGBLC03C 1 2
.param
+vc0 = 5.712e-12	vc1 = 5.307e-9		vc2 = 3.612e-10		vc3 = 3.436
+tc1 = 1.733e-1		tc2 = 3.724e-2		tc3 = 5.237e-3		tc4 = -2.871e-3
d1 1 c zener
d2 2 c zener
g1 c 1 value = {(vc0+vc1*v(c,1))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc2*exp(vc3*v(c,1)))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
g2 c 2 value = {(vc0+vc1*v(c,2))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc2*exp(vc3*v(c,2)))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model zener d
***** flag parameter ***
+level = 1   
***** dc model parameter ***
+ is = 1e-15	   	   n = 1.100		  rs = 1e-3
+ibv = 1e-3		 nbv = 1		  bv = 4.3
***** capacitance parameter ***
+cjo = 8.467e-13	   m = 7.452e-3		  vj = 3.812e-2
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25		  eg = 1.100		 xti = 3
+trs1 = 1e-4		tbv1 = -5.042e-4	tbv2 = -1.417e-6
.ends PJGBLC03C
*$
